SVN과 Maven을 이용한 자동화 빌드 배치 스크립트

@echo off
setlocal enabledelayedexpansion

:: UTF-8 인코딩 설정
chcp 65001

:: 작업 디렉토리를 프로젝트 폴더로 변경
cd /d D:\Projects\MyProject

:: 로그 파일 경로 설정
set LOGFILE=%USERPROFILE%\Desktop\myproject_build.log

:: 로그 파일에 현재 날짜 및 시간 기록
echo.>> "%LOGFILE%"
echo ========================= >> "%LOGFILE%"
echo %date% %time% >> "%LOGFILE%"
echo ========================= >> "%LOGFILE%"

:: SVN 업데이트 실행 및 로그 파일에 기록
echo Running SVN update... >> "%LOGFILE%"
svn update >> "%LOGFILE%" 2>&1

:: Maven 빌드 실행 및 로그 파일에 기록 (테스트 생략)
echo Running Maven build... >> "%LOGFILE%"
mvn clean package -DskipTests -Dfile.encoding=UTF-8 -e -fae >> "%LOGFILE%" 2>&1

:: 빌드 성공 여부 확인 후 이벤트 로그에 기록
if %ERRORLEVEL% equ 0 (
    echo Build completed successfully. >> "%LOGFILE%"
    powershell -Command "Write-EventLog -LogName Application -Source 'MyProject Maven Build & Deploy' -EventId 100 -EntryType Information -Message 'Build completed successfully.'" >> "%LOGFILE%" 2>&1
) else (
    echo Build failed. >> "%LOGFILE%"
    powershell -Command "Write-EventLog -LogName Application -Source 'MyProject Maven Build & Deploy' -EventId 101 -EntryType Error -Message 'Build failed.'" >> "%LOGFILE%" 2>&1
)

echo Build process finished. >> "%LOGFILE%"

 

 

 

분석

@echo off

배치 파일 실행 시 명령어를 화면에 출력하지 않도록 설정

 

setlocal enabledelayedexpansion

변수 값을 실시간으로 업데이트할 수 있도록 지연된 확장을 활성화

 

chcp 65001

UTF-8 인코딩을 사용하여 로그 파일이나 콘솔에서 한글이 깨지지 않도록 설정

 

cd /d D:\Projects\MyProject

작업 디렉토리를 D:\Projects\MyProject로 변경

 

set LOGFILE=%USERPROFILE%\Desktop\myproject_build.log

로그 파일을 사용자 바탕화면에 생성하도록 설정

 

echo.>> "%LOGFILE%"
echo ========================= >> "%LOGFILE%"
echo %date% %time% >> "%LOGFILE%"
echo ========================= >> "%LOGFILE%"

빌드 로그의 가동성을 높이기 위해 헤더 추가

=========================
2025-03-28 12:34:56.78
=========================

이런 식으로 추가된다.

 

svn update >> "%LOGFILE%" 2>&1

SVN 저장소에서 최신 코드 업데이트하고 로그 파일에 기록

2>&1 : 표준 에러 출력(2번)을 표준 출력(1번)으로 합친다는 듯 

 

mvn clean package -DskipTests -Dfile.encoding=UTF-8 -e -fae >> "%LOGFILE%" 2>&1

Maven을 사용하여 프로젝트를 빌드하며, 테스트는 생략 (-DskipTests)

테스트 생략 : 시간이 많이 걸려서 빌드만 하기도 하고, 다른 곳에서 테스트를 실행하고 있다면 굳이 필요 없다고 판단하여 추가되어있는 것.

-e : 에러가 발생하면 상세한 로그 출력

-fae : 에러 발생 시에도 가능한 한 계속 진행

 

if %ERRORLEVEL% equ 0 (...) else (...)

%ERRORLEVEL% 값이 0이면 빌드 성공, 0이 아니면 실패로 판단.

마지막 명령어는 'mvn clean package'인데 성공하면 0, 실패하면 다른 값으로 반환됨.

 

1 : 일반적인 오류(예: 파일 없음, 실행 실패)

2 : 잘못된 명령어 인수

100 : Maven 빌드 실패 (일반적으로 100)

101 : 특정한 오류 상황(예: 네트워크 오류)

 

powershell -Command "Write-EventLog -LogName Application -Source 'MyProject Maven Build & Deploy' -EventId 100 -EntryType Information -Message 'Build completed successfully.'" >> "%LOGFILE%" 2>&1

성공 시 : 윈도우 이벤트 로그(Application 로그)에 빌드 성공 기록

 

powershell -Command "Write-EventLog -LogName Application -Source 'MyProject Maven Build & Deploy' -EventId 101 -EntryType Error -Message 'Build failed.'" >> "%LOGFILE%" 2>&1

 

실패 시 : 이벤트 로그에 빌드 실패 메시지 기록

 

echo Build process finished. >> "%LOGFILE%"

전체 빌드 프로세스가 완료되었음을 로그 파일에 기록 

 

 

 

 

enabledelayedxpansion 사용하는 이유

setlocal enabledelayedexpansion

배치 파일에서 기본적으로 변수(%변수명%)은 한 번 값이 설정되면 그 줄이 실행될 때까지만 유지됨.

하지만 위 명령어를 사용하면 !변수명! 형식으로 변수를 실시간 업데이트 가능

 

기본적인 변수 사용

@echo off
set count=0
for /L %%i in (1,1,5) do (
    set /a count+=1
    echo count = %count%   :: 여기선 항상 0으로 출력됨
)

 

결과

 

count = 0
count = 0
count = 0
count = 0
count = 0

 

 

!변수!를 사용한 실시간 업데이트

@echo off
setlocal enabledelayedexpansion
set count=0
for /L %%i in (1,1,5) do (
    set /a count+=1
    echo count = !count!   :: 1부터 5까지 증가하며 출력됨
)

 

결과

 

count = 1
count = 2
count = 3
count = 4
count = 5